blob: 5ce82a6f4bfabd82d77771e87bbbf49c62b43b47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Jan Hicken <firstname [dot] lastname [at] posteo [dot] de>
# Former maintainer: Robert Knauer <robert@privatdemail.net>
pkgname=fhem
pkgver=5.7
pkgrel=1
pkgdesc="A perl server for house automation"
arch=('any')
url='http://fhem.de'
license=('GPL')
depends=('perl' 'perl-io-socket-ssl' 'perl-json' 'perl-libwww' 'perl-xml-simple' 'perl-xml-libxml')
optdepends=('perl-device-serialport: Communication through serial port'
'perl-net-telnet: Telnet support'
'perl-net-snmp: SNMP support')
backup=('etc/fhem.cfg')
install="${pkgname}.install"
source=(
"http://fhem.de/${pkgname}-${pkgver}.tar.gz"
'fhem.service'
'sysusers.conf'
'tmpfiles.conf'
)
sha256sums=('179fd251edb0bc7dbd775d7d6597fcfe7df88c2f7b39c5bbecf17defaa6b9539'
'7adaffd1036198c8f942a7cbcdc187ba59557eccdfcd19aa28ed5f578810ce14'
'79c1235e00e7159622fe42d5963a87ed9c7f5ba677ee3e3e469ee271de0025c3'
'216cbb566c38b893f7036e8e32997a3595c1cf618688be00371d9d49f715a2bd')
prepare() {
cd "${pkgname}-${pkgver}"
# Fix path setup in Makefile
sed -i 's|^RELATIVE_PATH=YES|RELATIVE_PATH=NO|' Makefile
sed -i 's|^BINDIR=.*|BINDIR=/usr/bin|' Makefile
sed -i 's|^MODDIR=.*|MODDIR=/usr/share/fhem|' Makefile
sed -i 's|^VARDIR=.*|VARDIR=/var/lib/fhem|' Makefile
sed -i 's|^MANDIR=.*|MANDIR=/usr/share/man/man1|' Makefile
sed -i 's|^ETCDIR=.*|ETCDIR=/etc|' Makefile
sed -i 's|^DEMODIR=.*|DEMODIR=/usr/share/fhem|' Makefile
}
package() {
install -Dm 0644 fhem.service "${pkgdir}/usr/lib/systemd/system/fhem.service"
install -Dm 0644 sysusers.conf "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -Dm 0644 tmpfiles.conf "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
cd "${pkgname}-${pkgver}"
make ROOT="${pkgdir}" install
# Remove unnecessary stuff
rm -r "${pkgdir}/usr/share/fhem/contrib/DEBIAN"
rm -r "${pkgdir}/usr/share/fhem/contrib/FB7270"
rm -r "${pkgdir}/usr/share/fhem/contrib/FB7390"
rm -r "${pkgdir}/usr/share/fhem/contrib/init-scripts"
rm -r "${pkgdir}/usr/share/fhem/contrib/lcd4linux"
rm -r "${pkgdir}/usr/share/fhem/contrib/PRESENCE/deb"
rm -r "${pkgdir}/usr/share/fhem/contrib/RaspberryPi"
rm -r "${pkgdir}/usr/share/fhem/contrib/Synology"
rmdir --ignore-fail-on-non-empty --parents "${pkgdir}/var/lib/fhem"
}
|