blob: 1320161e99a204377941e37507d9e55c0b60a247 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
pkgname=fheroes2
pkgver=1.0.0
pkgrel=2
pkgdesc="Recreation of the Heroes of Might and Magic II game engine"
arch=('i686' 'x86_64' 'armv7h')
url="https://ihhub.github.io/fheroes2/"
license=('GPL2')
depends=('sdl2' 'sdl2_image' 'sdl2_mixer')
optdepends=('curl: download demo version files'
'python: extract animation resources from GOG CD image'
'wget: download demo version files'
'unzip: unpack demo version files')
makedepends=('cmake' 'gettext' 'ninja')
conflicts=('fheroes2-git')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/ihhub/$pkgname/archive/$pkgver.tar.gz"
)
sha256sums=('80468b4eaf128ac5179a3416a02e2a2ef4ab34d90876b179fccd8d505f950440')
build() {
cd "$srcdir/$pkgname-$pkgver"
cmake -B build -G Ninja -S . \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
make -C docs
}
package() {
cd "$srcdir/$pkgname-$pkgver"
DESTDIR="$pkgdir" cmake --install build
install -dm755 "$pkgdir/usr/share/fheroes2/maps"
install -Dm644 docs/fheroes2.6 "$pkgdir/usr/share/man/man6/fheroes2.6"
}
# vim:set ts=2 sw=2 et:
|