PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# NOTE: You must manually download "xp9.8.0_linux_x86_64_setup.tar" from:
# https://www.fico.com/en/fico-xpress-community-license
# And place it in the same directory where you're going to compile this package 
# (or in ~/.cache/yay/fico-xpress-bin/ if you're using yay).

pkgname=fico-xpress-bin
pkgver=9.8.0
pkgrel=3
pkgdesc="FICO Xpress Optimization Suite (Mosel & Solver)"
arch=('x86_64')
url="https://www.fico.com/en/fico-xpress-community-license"
license=('custom:commercial')
depends=('gcc-libs' 'bash')
provides=('fico-xpress')
conflicts=('fico-xpress')
options=('!strip')
install="${pkgname}.install"

source=("local://xp${pkgver}_linux_x86_64_setup.tar")
sha256sums=('7984e5476b0dde4e8c1995c1c0057bd4ebc43d5484de6c05cca8846d01734c8b')

package() {
    cd "${srcdir}/xp${pkgver}_linux_x86_64_setup"

    install -dm755 "${pkgdir}/opt/xpressmp"

    ./install.sh \
        --no-interactive \
        --license-type community \
        --components full \
        --accept-xpress-license \
        --accept-kalis-license \
        --install-path "${pkgdir}/opt/xpressmp"

    sed -i "s|${pkgdir}||g" "${pkgdir}/opt/xpressmp/bin/xpvars.sh"
    sed -i "s|${pkgdir}||g" "${pkgdir}/opt/xpressmp/bin/xpvars.csh"

    # Inyectar las variables nativas generadas por FICO Xpress para Bash y Zsh 
    install -dm755 "${pkgdir}/etc/profile.d"
    echo '#!/bin/sh' > "${pkgdir}/etc/profile.d/fico-xpress.sh"
    echo 'source /opt/xpressmp/bin/xpvars.sh' >> "${pkgdir}/etc/profile.d/fico-xpress.sh"
    chmod 755 "${pkgdir}/etc/profile.d/fico-xpress.sh"
}