blob: ac8e17cb667e73a1d0017aa856a1732af8daa1cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Peter Mattern <pmattern at arcor dot de>
_pkgname=filezilla
pkgname=$_pkgname-svn
pkgver=11020
pkgrel=1
pkgdesc='Free, open source FTP, FTPS and SFTP client'
arch=('i686' 'x86_64')
url='https://filezilla-project.org'
license=('GPL')
depends=('libfilezilla-svn' 'wxwidgets-gtk3' 'xdg-utils')
makedepends=('subversion' 'pugixml' 'boost')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::svn+https://svn.filezilla-project.org/svn/FileZilla3/trunk")
sha256sums=("SKIP")
prepare() {
# Complement desktop entry file with key MimeTypes, https://trac.filezilla-project.org/ticket/10724
cd $_pkgname/data/
grep --quiet MimeType filezilla.desktop || echo 'MimeType=x-scheme-handler/ftp;' >> filezilla.desktop
}
pkgver() {
cd $_pkgname
svnversion | sed 's:M$::'
}
build() {
cd $_pkgname
autoreconf -i
./configure --prefix=/usr
make
}
package() {
cd $_pkgname
make DESTDIR=$pkgdir install
}
|