blob: 6c1fe34577e9f5889941b3fa5551c3dc128cb5c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer:
# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
# SELinux Contributor: Timothée Ravier
# SELinux Contributor: Nicky726 <Nicky726@gmail.com>
#
# This PKGBUILD is maintained on https://github.com/archlinuxhardened/selinux.
# If you want to help keep it up to date, please open a Pull Request there.
pkgname=findutils-selinux
pkgver=4.6.0
pkgrel=4
pkgdesc="GNU utilities to locate files with SELinux support"
arch=('x86_64')
license=('GPL3')
groups=('selinux')
depends=('glibc' 'sh' 'libselinux')
conflicts=("${pkgname/-selinux}" "selinux-${pkgname/-selinux}")
provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}"
"selinux-${pkgname/-selinux}=${pkgver}-${pkgrel}")
url='https://www.gnu.org/software/findutils'
source=("https://ftp.gnu.org/pub/gnu/findutils/${pkgname/-selinux}-${pkgver}.tar.gz"
"gnulib-fflush.patch"
"gnulib-makedev.patch")
sha1sums=('f18e8aaee3f3d4173a1f598001003be8706d28b0'
'1bc1586f6a52083939c4cabc32f12e7aead97e61'
'051382a2b0039438c2b143f2f9e5dc4bea130a09')
#validpgpkeys=('A15B725964A95EE5') # James Youngman <james@youngman.org> - NOTE: PGP-2 key
prepare() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
patch -p1 -i "$srcdir"/gnulib-fflush.patch
patch -p1 -i "$srcdir"/gnulib-makedev.patch
}
build() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
# Don't build or install locate because we use mlocate,
# which is a secure version of locate.
sed -i '/^SUBDIRS/s/locate//' Makefile.in
autoreconf
./configure --prefix=/usr
# don't build locate, but the docs want a file in there.
make -C locate dblocation.texi
make
}
check() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
make DESTDIR="$pkgdir" install
}
|