blob: 605489198a6d1d942be63bbc8de0b1c055a38156 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id$
# SELinux Maintainer: Timothée Ravier
# SELinux Contributor: Nicky726 <Nicky726@gmail.com>
pkgname=findutils-selinux
pkgver=4.4.2
pkgrel=5
pkgdesc="GNU utilities to locate files with SELinux patch"
arch=('i686' 'x86_64')
license=('GPL3')
groups=('selinux')
depends=('glibc' 'sh' 'libselinux')
conflicts=("${pkgname/-selinux}")
provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}")
url="http://www.gnu.org/software/findutils"
source=("ftp://ftp.gnu.org/pub/gnu/findutils/${pkgname/-selinux}-${pkgver}.tar.gz"{,.sig}
"http://sources.gentoo.org/cgi-bin/viewvc.cgi/gentoo-x86/sys-apps/${pkgname/-selinux}/files/${pkgname/-selinux}-${pkgver}-selinux.diff")
install=findutils.install
sha1sums=('e8dd88fa2cc58abffd0bfc1eddab9020231bb024'
'77d9585d9feea0814752a31bf109fe287f528243'
'96318be5586d324a13805da81907406a95c6514c')
prepare() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
# SELinux patch
patch -Np1 -i "${srcdir}/${pkgname/-selinux}-${pkgver}-selinux.diff"
}
build() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
# Don't build or install locate because we use mlocate,
# which is a secure version of locate.
sed -i '/^SUBDIRS/s/locate//' Makefile.in
./configure --prefix=/usr
make
}
check() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname/-selinux}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|