blob: 3d4d5c2144315b62640b42232a95d14667bf6f97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Benjamin Denhartog <ben@sudoforge.com>
# Contributor: Raphaël Doursenaud <rdoursenaud@free.fr>
# Contributor: crasm <crasm@firebase-tools.aur.yooz4sio.vczf.io>
pkgname=firebase-tools
pkgver=9.7.0
pkgrel=1
pkgdesc="The Firebase Command Line Tools"
arch=('any')
url="https://github.com/firebase/firebase-tools"
license=('MIT')
depends=('nodejs')
makedepends=(
'npm'
'jq'
)
source=("https://registry.npmjs.org/${pkgname}/-/${pkgname}-${pkgver}.tgz")
noextract=("${pkgname}-${pkgver}.tgz")
sha256sums=('a36a1a547ecd2164fa939e87421b90ddaf87ac88d1b02e62b8bcfb2252082409')
package() {
# We throw away output here to keep the build quieter; if issues are
# encountered, be sure to remove the output redirection in order to debug.
npm install \
--global \
--user root \
--prefix "${pkgdir}/usr" \
"${srcdir}/${pkgname}-${pkgver}.tgz" &> /dev/null
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/npm/issues/9359 for details.
find "${pkgdir}/usr" -type d -exec chmod 755 {} +
# Remove references to the package directory
find "$pkgdir" -name package.json -print0 | xargs -r -0 sed -i '/_where/d'
# Remove references to the package directory from package.json
find "$pkgdir" \
-type f \
-name 'package.json' \
-execdir sh -c "jq '. | delpaths([paths|select(.[0] | test(\"_.*\"))])' {} > {}.new" \; \
-exec mv {}.new {} \;
# sshpk contains build references in the `man` attribute...
find "${pkgdir}/usr/lib/node_modules/${pkgname}/node_modules/sshpk/package.json" \
-execdir sh -c "jq '.man = [[\
\"man/man1/sshpk-conv.1\", \
\"man/man1/sshpk-sign.1\", \
\"man/man1/sshpk-verify.1\" \
]]' {} > {}.new" \; \
-exec mv {}.new {} \;
# Install a symlink for the LICENSE file
install -d "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s \
"/usr/lib/node_modules/${pkgname}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|