blob: f803051d5960e29a064a37db40f490970a9f0d15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
pkgname=firefox-tridactyl-git
pkgver=1.21.1.r143.g5a11a97f
pkgrel=1
pkgdesc="Replace Firefox's control mechanism with one modelled on Vim"
url=https://github.com/tridactyl/tridactyl
arch=('any')
license=('Apache')
groups=('firefox-addons')
makedepends=('git' 'node-gyp' 'python' 'strip-nondeterminism' 'yarn')
source=("git+$url.git")
sha512sums=('SKIP')
pkgver() {
cd tridactyl
git describe --long --tags | sed 's/-/.r/;s/-/./'
}
build() {
cd tridactyl
yarn install --frozen-lockfile --non-interactive
scripts/sign nosignbeta
strip-nondeterminism -t zip web-ext-artifacts/tridactyl-$pkgver.xpi
}
package() {
cd tridactyl
install -Dm644 web-ext-artifacts/tridactyl_beta-${pkgver%%.r*}.xpi \
"$pkgdir"/usr/lib/firefox/browser/extensions/tridactyl.vim.betas@cmcaine.co.uk.xpi
}
# vim:set ts=2 sw=2 et:
|