blob: b180a3e5060ba62a47bc1b4f13bad506eec44100 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: dudemanguy <random342@airmail.cc>
# Contributor: LA-MJ <4mr.minj+aur [at] g-mail>
pkgname=firefox-unbranded-bin
pkgver=66.0.4
pkgrel=1
pkgdesc="Standalone web browser from mozilla.org - Unbranded version"
arch=('x86_64')
url=https://wiki.mozilla.org/Add-ons/Extension_Signing#Unbranded_Builds
provides=(firefox=$pkgver)
conflicts=(firefox)
license=('MPL' 'GPL' 'LGPL')
depends=('dbus-glib' 'gtk3' 'libxt' 'nss' 'mime-types')
optdepends=('pulseaudio: audio support'
'ffmpeg: h.264 video'
'hunspell: spell checking'
'hyphen: hyphenation'
'libnotify: notification integration'
'networkmanager: location detection via available WiFi networks'
'speech-dispatcher: text-to-speech'
'startup-notification: support for FreeDesktop Startup Notification')
_url="https://queue.taskcluster.net/v1/task/L8NaY3ZeRIyHb_ZpmKGcHQ/runs/0/artifacts/public/build/target.tar.bz2"
source=(${_url}
firefox.desktop)
sha256sums=('6aab83542f8875fed03072594242afb6db990155f7e968ae6cf1ee2b21374490'
'4a783dca1f88e003c72f32d22719a0915f3fa576adbc492240e7cc250246ce10')
package() {
OPT_PATH="/opt/firefox"
install -d "${pkgdir}"/{usr/bin,opt}
cp -r firefox "${pkgdir}"/${OPT_PATH}
ln -s "/${OPT_PATH}/firefox" "${pkgdir}"/usr/bin/firefox
# Install .desktop files
install -Dm644 "${srcdir}"/firefox.desktop -t "${pkgdir}"/usr/share/applications
# Install Icons
SRC_LOC="${srcdir}"/firefox/browser
DEST_LOC="${pkgdir}"/usr/share/icons/hicolor
for i in 16 32 48 64 128
do
install -Dm644 "${SRC_LOC}"/chrome/icons/default/default${i}.png "${DEST_LOC}"/${i}x${i}/apps/firefox.png
done
# Use system-provided dictionaries
rm -rf "${pkgdir}"/${OPT_PATH}/{dictionaries,hyphenation}
ln -sf /usr/share/hunspell "${pkgdir}"/${OPT_PATH}/dictionaries
ln -sf /usr/share/hyphen "${pkgdir}"/${OPT_PATH}/hyphenation
}
|