blob: 731ad00e3effce31f90a24de7d87269555cf587a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Arnoud Willemsen <mail at lynthium dot com>
pkgname=firejail-git
pkgver=0.9.70.r8682.160ccd3d9
pkgrel=1
pkgdesc="Linux namespaces sandbox program (GIT version)"
arch=(i686 x86_64)
license=(GPL2)
url="https://github.com/netblue30/firejail"
source=("${pkgname}::git+https://github.com/netblue30/firejail.git")
install=firejail.install
sha512sums=('SKIP')
conflicts=('firejail')
provides=('firejail')
depends=('apparmor')
optdepends=('xdg-dbus-proxy')
makedepends=('git')
backup=('etc/firejail/login.users'
'etc/apparmor.d/local/firejail-default'
'etc/firejail/firejail.config'
'etc/firejail/firecfg.config')
pkgver() {
cd "${srcdir}/${pkgname}"
printf "%s.r%s.%s" "$(git describe --tags --abbrev=0)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" | sed 's/^v//;s/-/./g'
}
build() {
cd "${srcdir}/${pkgname}"
./configure --prefix=/usr --enable-apparmor
make
}
package() {
cd "${srcdir}/${pkgname}"
make DESTDIR="${pkgdir}" install
}
# vim: set ts=2 sw=2 et:
|