blob: d5b592bc56136eda7bec6a9db8ee4a132e5deee2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Amanoel Dawod <amoka at amanoel dot com>
# Contributor: Elliott Saille <me+aur@esaille.me>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: unikum <unikum.pm@gmail.com>
# Contributor: speed145a <jonathan@tagchapter.com>
pkgname=firewalld-git
pkgver=r3296.f3bd1297
pkgrel=1
epoch=1
pkgdesc="Firewall daemon with D-Bus interface (from git)"
arch=(any)
url="https://firewalld.org/"
license=(GPL2)
depends=(
dconf
glib2
hicolor-icon-theme
nftables
python-decorator
python-gobject
python-slip
)
makedepends=(
docbook-xsl
git
intltool
ipset
)
optdepends=(
'bash-completion: bash completion'
'gtk3: firewall-config'
'ipset: ipset support'
'libnotify: firewall-applet'
'nm-connection-editor: firewalld-applet'
'python-pyqt5: firewall-applet'
)
provides=('firewalld')
conflicts=('firewalld')
backup=(
etc/conf.d/firewalld
etc/firewalld/firewalld.conf
)
source=(
git+https://github.com/firewalld/firewalld.git
firewalld-sysconfigdir.patch
)
sha256sums=('SKIP'
'cf7d655230c43acf10a0f97dffdbcba136729967c8b9a25a930871d54a589834')
pkgver() {
cd firewalld
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd firewalld
patch -Np1 -i ../firewalld-sysconfigdir.patch
NOCONFIGURE=true ./autogen.sh
}
build() {
cd firewalld
./configure \
--prefix=/usr \
--localstatedir=/var \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--disable-schemas-compile \
--disable-sysconfig
make
}
package() {
make DESTDIR="${pkgdir}" -C firewalld install
export PYTHONHASHSEED=0
python -m compileall -d /usr/lib "$pkgdir/usr/lib"
python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
}
|