blob: b1800160ecceb6a7fb4d41cce8965025b761ad0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Jan Fader <jan.fader@web.de>
# Contributor: Stephen Drodge <stephen.drodge@gmail.com>
# Contributor: akiirui (AUR)
# Maintainer: SanskritFritz (gmail)
pkgname=fish-git
_gitname="fish-shell"
pkgver=3.1.2.r2055.gc633ce7e7
pkgrel=1
epoch=2
pkgdesc="User friendly shell intended mostly for interactive use."
arch=('i686' 'x86_64' 'arm')
url="http://fishshell.com"
license=("GPL2")
depends=('glibc' 'gcc-libs' 'ncurses' 'pcre2')
optdepends=('python: man page completion parser / web config tool'
'pkgfile: command-not-found hook'
'wl-clipboard: clipboard integration'
'xsel: clipboard integration'
'xclip: clipboard integration')
makedepends=('cmake' 'python-sphinx' 'git')
checkdepends=('expect')
provides=('fish' 'fish-shell')
conflicts=('fish' 'fish-shell')
install='fish.install'
source=("git://github.com/fish-shell/fish-shell.git")
md5sums=('SKIP')
pkgver() {
cd "$_gitname"
git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
check() {
cd "$_gitname"
make -C build test
}
build() {
cd "$_gitname"
export CXXFLAGS+=" ${CPPFLAGS}"
cmake \
-B build \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_SYSCONFDIR=/etc \
-DCMAKE_BUILD_TYPE=None \
-DBUILD_DOCS=True \
-Wno-dev
make -C build
}
package() {
cd "$_gitname"
make -C build DESTDIR="$pkgdir" install
}
|