blob: b69dca573f3efb935fcb638ae0064e07888e5acb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: envolution
# Contributor: László Várady <laszlo.varady93@gmail.com>
# Contributor: Aleksandar Trifunović <akstrfn at gmail dot com>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=fizz
pkgver=2025.07.07.00
pkgrel=1
pkgdesc="C++14 implementation of the TLS-1.3 standard"
arch=(x86_64)
url="https://github.com/facebookincubator/fizz"
license=(BSD-3-Clause)
depends=(
double-conversion
fmt
folly=$pkgver
gcc-libs
gflags
glibc
google-glog
libsodium
openssl
zlib
zstd
)
makedepends=(
boost
cmake
gtest
)
checkdepends=(expat)
provides=(
libfizz.so
libfizz_test_support.so
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('86635b14d000c6e8e61a3edfbd9ad51764c9bf84b3702d73ac6dadff97786c99')
prepare() {
cd $pkgname-$pkgver
# Use system CMake config instead of bundled module
sed -i 's/find_package(Glog REQUIRED)/find_package(Glog CONFIG REQUIRED)/' \
fizz/CMakeLists.txt
}
build() {
cd $pkgname-$pkgver
cmake -S fizz -B build \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-Wno-dev \
-DBUILD_TESTS=ON \
-DBUILD_SHARED_LIBS=ON \
-DPACKAGE_VERSION="$pkgver"
cmake --build build
}
check() {
cd $pkgname-$pkgver
ctest --test-dir build --output-on-failure
}
package() {
cd $pkgname-$pkgver
DESTDIR="$pkgdir" cmake --install build
# Remove empty directories to avoid namcap warnings
rm -vfr "$pkgdir/usr/include/fizz/tool/test"
rm -vfr "$pkgdir/usr/include/fizz/util/test"
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
# vim:set ts=2 sw=2 et:
|