blob: e2a812aa1f0b6eeb629e0af25ef331e5a6615cd1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: patrickjaja <patrickjajaa@gmail.com>
pkgname=flameshot-imgur
_pkgname=flameshot
pkgver=13.3.0
pkgrel=1
pkgdesc="Powerful yet simple to use screenshot software with Imgur upload support enabled"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://github.com/flameshot-org/flameshot"
license=('GPL-3.0-or-later')
depends=('qt6-base' 'qt6-svg' 'hicolor-icon-theme' 'kguiaddons')
makedepends=('qt6-tools' 'cmake' 'ninja')
optdepends=(
'gnome-shell-extension-appindicator: for system tray icon if you are using Gnome'
'grim: for wlroots wayland support'
'xdg-desktop-portal: for wayland support, you will need the implementation for your wayland desktop environment'
'qt6-imageformats: for additional export image formats (e.g. tiff, webp, and more)'
)
provides=('flameshot')
conflicts=('flameshot' 'flameshot-git' 'flameshot-imgur-git')
options=('!debug')
source=("$_pkgname-$pkgver.tar.gz::https://github.com/flameshot-org/flameshot/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('bd1666313c875400e9588b47eb3fd2f4d0828460b3705a215b97746ea654c1b4')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
cmake -GNinja -B build -S . \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DUSE_WAYLAND_CLIPBOARD=1 \
-DDISABLE_UPDATE_CHECKER=1 \
-DENABLE_IMGUR=ON
cmake --build build
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
DESTDIR="${pkgdir}" cmake --install build
}
|