blob: 56a60bc1dcaad31ea9e377cc750d7423fc08fe6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Zach Hoffman <zach@zrhoffman.net>
pkgname=(flashplugin-debug pepper-flash-debug)
pkgver=32.0.0.223
pkgrel=1
pkgdesc="Adobe Flash Player debugger"
arch=('x86_64')
url="https://www.adobe.com/support/flashplayer/debug_downloads.html"
license=('custom' 'LGPL')
options=('!strip')
source=(flash_player_npapi_linux_debug_$pkgver.x86_64.tar.gz::https://fpdownload.macromedia.com/pub/flashplayer/updaters/32/flash_player_npapi_linux_debug.x86_64.tar.gz
flash_player_ppapi_linux_debug_$pkgver.x86_64.tar.gz::https://fpdownload.macromedia.com/pub/flashplayer/updaters/32/flash_player_ppapi_linux_debug.x86_64.tar.gz)
noextract=(${source[@]%::*})
sha256sums=('4308f5b933fff849217b8298d64b8b98cce79b04b77bc4261a5effdf08d4bf98'
'b6384516e19f0d58c75bebd1c254cb5a6c7843c5938c537179db9709f26149d8')
prepare() {
local _dir
for f in ${noextract[@]}; do
_dir=$(grep -Eo '([np]papi)' <<< $f)
mkdir -p $_dir
tar xfC $f $_dir
done
}
package_flashplugin-debug() {
pkgdesc+=" NPAPI"
depends=('libxt' 'gtk2' 'nss' 'curl' 'hicolor-icon-theme')
optdepends=('libvdpau: GPU acceleration on Nvidia cards')
provides=("flashplugin=${pkgver}")
conflicts=('flashplugin')
cd npapi
install -Dm644 libflashplayer.so "$pkgdir/usr/lib/mozilla/plugins/libflashplayer.so"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" license.pdf LGPL/notice.txt
install -D -t "$pkgdir/usr/bin" usr/bin/flash-player-properties
cp -a usr/share/{applications,icons} "$pkgdir/usr/share/"
}
package_pepper-flash-debug() {
pkgdesc+=" PPAPI"
depends=('gcc-libs')
optdepends=('flashplugin-debug: settings utility')
provides=("pepper-flash=${pkgver}")
conflicts=('pepper-flash')
cd ppapi
install -Dm644 -t "$pkgdir/usr/lib/PepperFlash" manifest.json libpepflashplayer.so
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" license.pdf LGPL/notice.txt
}
# vim:set ts=2 sw=2 et:
|