summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8c830df650dfba2b47c2c92f228556610e8139e6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Dušan Simić <dusan.simic1810@gmail.com>

pkgname=flatpak-builder-lint-git
_reponame="${pkgname%-git}"
pkgver=r147.3c8daa9
pkgrel=1
pkgdesc='A linter for flatpak-builder manifests'
arch=(any)
url="https://github.com/flathub/$_reponame"
license=(MIT)
depends=(python python-requests python-jsonschema flatpak-builder)
makedepends=(git python-build python-installer python-wheel python-poetry)
provides=("$_reponame")
conflicts=("$_reponame")
source=("git+$url")
md5sums=('SKIP')

pkgver() {
	cd "$srcdir/$_reponame"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$_reponame"
	python -m build --wheel --no-isolation
}

package() {
	cd "$_reponame"
	python -m installer --destdir="$pkgdir" dist/*.whl
	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}