blob: fc06b57f1aeadf050c3941b21e9a749a34378be7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Nebulosa <nebulosa2007-at-yandex-dot-ru>
pkgname=flatpak-ext-git
pkgver=0.1.3.r57.g8a6376c
pkgrel=1
pkgdesc="Tool for run flatpaks without installing them"
arch=(x86_64)
url="https://github.com/ryanabx/${pkgname%-git}"
license=(MIT)
depends=(
flatpak
gcc-libs
glib2
glibc
openssl
)
makedepends=(
clang
git
rust
)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
options=(!debug)
source=(${pkgname%-git}::git+$url)
b2sums=('SKIP')
pkgver() {
git -C ${pkgname%-git} describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
prepare() {
cd ${pkgname%-git}
export RUSTUP_TOOLCHAIN=stable
export CARGO_HOME="$srcdir"/.cargo
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd ${pkgname%-git}
export RUSTUP_TOOLCHAIN=stable
export CARGO_HOME="$srcdir"/.cargo
export RUSTFLAGS="--remap-path-prefix=$srcdir=/"
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd ${pkgname%-git}
install -vDm755 target/release/flatpak-ext -t "$pkgdir"/usr/bin/
install -vDm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}
|