blob: cbb71f6263ab7abb91bc953010b78f6546ae2dc0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=flex-git
pkgver=2.6.4.r442.g4a4bac0
pkgrel=1
pkgdesc="The Fast Lexical Analyzer - scanner generator for lexing in C and C++"
arch=('i686' 'x86_64')
url="https://github.com/westes/flex"
license=('custom')
depends=('glibc' 'm4' 'sh')
makedepends=('git' 'help2man' 'texinfo')
provides=("flex=$pkgver")
conflicts=('flex')
options=('staticlibs')
source=("git+https://github.com/westes/flex.git")
sha256sums=('SKIP')
pkgver() {
cd "flex"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "flex"
./autogen.sh
./configure \
--prefix="/usr"
make
}
check() {
cd "flex"
make check
}
package() {
cd "flex"
make DESTDIR="$pkgdir" install
ln -s flex "$pkgdir/usr/bin/lex"
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/flex"
}
|