PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer : Daniel Bermond < yahoo-com: danielbermond >
# Contributor: John Jenkins <twodopeshaggy@gmail.com>

pkgname=flif
_srcname=FLIF
pkgver=0.3
pkgrel=3
pkgdesc='Free Lossless Image Format'
arch=('i686' 'x86_64')
url='https://github.com/FLIF-hub/FLIF/'
license=('LGPL3' 'APACHE')
depends=('gcc-libs' 'libpng' 'sdl2')
optdepends=(
    # official repositories:
        'imagemagick: for gif2flif tool'
    # AUR:
        'apng-utils: for apng2flif tool'
)
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/FLIF-hub/FLIF/archive/v${pkgver}.tar.gz"
        'flif-use-build-flags.patch')
sha256sums=('aa02a62974d78f8109cff21ecb6d805f1d23b05b2db7189cfdf1f0d97ff89498'
            'd8cdb93f4f1e63487d65d23c1c96bf79acff1277532cbcfd88ca05932655d871')

prepare() {
    cd "${_srcname}-${pkgver}"
    
    # use build flags
    patch -Np1 -i "${srcdir}/flif-use-build-flags.patch"
    
    # remove apt-get references from installed tools
    cd tools
    sed -i '/apt-get/d' gif2flif apng2flif
}

build() {
    cd "${_srcname}-${pkgver}/src"
    
    local _target
    
    for _target in all decoder viewflif
    do
        printf '%s\n' "  -> Building target '${_target}'..."
        make "$_target"
    done
    
}

package() {
    cd "${_srcname}-${pkgver}/src"
    
    local _target
    
    for _target in install{,-dev,-decoder,-viewflif}
    do
        printf '%s\n' "  -> Installing target '${_target}'..."
        make PREFIX="${pkgdir}/usr" "$_target"
    done
}