blob: b1768edb8c38e5ab47e53a2e4629bd073be342ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Mahdi Sarikhani <mahdisarikhani@outlook.com>
# Contributor: Alexander Fetting <deeznuts420692@proton.me>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
# Contributor: Ashley Whetter <(firstname) @ awhetter.co.uk>
# Contributor: Deon Spengler <deon at spengler dot co dot za>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Hans Janssen <hans@janserv.xs4all.nl>
pkgname=flightgear
pkgver=2024.1.7
pkgrel=1
pkgdesc="An open-source, multi-platform flight simulator"
arch=('x86_64')
url="https://www.flightgear.org"
license=("GPL-2.0-or-later")
depends=('dbus'
'glibc'
'gsm'
'hicolor-icon-theme'
'libevent'
'libgcc'
'libglvnd'
'libstdc++'
'libx11'
'openal'
'openscenegraph'
'qt6-base'
'qt6-declarative'
'simgear'
'speex'
'speexdsp'
'sqlite'
'systemd-libs'
'zlib')
makedepends=('boost' 'cmake' 'plib' 'qt6-svg' 'qt6-tools')
optdepends=('flightgear-data: Base data package')
source=("https://gitlab.com/flightgear/flightgear/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('b1e6d621c93e00a9374dcaca0260006f80731191c3195f3077de7f80a5e65b96')
prepare() {
cd "${pkgname}-${pkgver}"
sed -i 's|Exec=\(.*\)|Exec=\1 --fg-root=/usr/share/flightgear/data|' package/org.flightgear.FlightGear.desktop.in
}
build() {
local cmake_options=(
-B build
-D CMAKE_BUILD_TYPE=Release
-D CMAKE_INSTALL_PREFIX=/usr
-D CHECK_FOR_QT5=OFF
-D ENABLE_CCACHE=ON
-D FG_DATA_DIR=/usr/share/flightgear/data
-D SYSTEM_SQLITE=ON
-S "${pkgname}-${pkgver}"
)
cmake "${cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
rm -r "${pkgdir}/usr/appdir"
}
|