blob: 890cbfdef84e3377aa31e45eadd304a7c446b9f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Ashley Whetter <(firstname) @ awhetter.co.uk>
# Contributor: Deon Spengler <deon at spengler dot co dot za>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Hans Janssen <hans@janserv.xs4all.nl>
pkgname='flightgear'
pkgver=2020.3.1
_pkgver=${pkgver%.*}
pkgrel=1
pkgdesc="An open-source, multi-platform flight simulator"
arch=('x86_64')
depends=('libxmu' 'libxi' 'zlib' 'openscenegraph' 'libxrandr' 'glu' 'openal')
makedepends=('boost' 'cmake' 'mesa' 'sharutils' 'simgear' 'qt5-base' 'qt5-declarative' 'qt5-svg')
optdepends=('qt5-base: fgfs --launcher'
'qt5-declarative: fgfs --launcher'
'flightgear-data')
license=("GPL")
url="http://www.flightgear.org/"
options=('makeflags')
source=("http://downloads.sourceforge.net/project/flightgear/release-${_pkgver}/${pkgname}-${pkgver}.tar.bz2")
sha256sums=('8860d13f8ca41d387dce1850b90650c5e440e3e2505021180d303dfa4784d103')
prepare() {
cd "$srcdir"/flightgear-$pkgver
sed -i 's|Exec=.*|Exec=fgfs --fg-root=/usr/share/flightgear/data|' package/org.flightgear.FlightGear.desktop
}
build() {
mkdir -p "$srcdir"/flightgear-build
cd "$srcdir"/flightgear-build
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DFG_DATA_DIR:STRING="/usr/share/flightgear/data" \
-DCMAKE_BUILD_TYPE=Release \
-DFG_BUILD_TYPE=Release \
../flightgear-$pkgver
make
}
package() {
cd "$srcdir"/flightgear-build
make DESTDIR="$pkgdir" install
cd "$srcdir"/flightgear-$pkgver
install -Dm0644 package/flightgear.ico "$pkgdir"/usr/share/icons/flightgear.ico
install -Dm0644 scripts/completion/fg-completion.bash "$pkgdir"/usr/share/bash-completion/completions/fgfs
install -Dm0644 scripts/completion/fg-completion.zsh "$pkgdir"/usr/share/zsh/site-functions/_fgfs
ln -sf flightgear "$pkgdir"/usr/share/FlightGear
}
|