blob: 8ae7f7c7c6c1cecb6ff36f5a0bdbc4cc19c34073 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Daniel Peukert <daniel@peukert.cc>
# Contributor: Joel Goguen <contact+aur@jgoguen.ca>
# Contributor: Jordan Klassen <forivall@gmail.com>
_pkgname='flow'
pkgname="$_pkgname-bin"
pkgver='0.231.0'
pkgrel='1'
pkgdesc='A static type checker for JavaScript - binary version'
arch=('x86_64' 'aarch64')
url="https://$_pkgname.org"
license=('MIT')
provides=("$_pkgname")
conflicts=("$_pkgname")
source_x86_64=(
"$pkgname-$pkgver-x86_64.zip::https://github.com/facebook/$_pkgname/releases/download/v$pkgver/$_pkgname-linux64-v$pkgver.zip"
"$pkgname-$pkgver-parser-x86_64.zip::https://github.com/facebook/$_pkgname/releases/download/v$pkgver/lib${_pkgname}parser-linux64-v$pkgver.zip"
)
source_aarch64=(
"$pkgname-$pkgver-aarch64.zip::https://github.com/facebook/$_pkgname/releases/download/v$pkgver/$_pkgname-linux-arm64-v$pkgver.zip"
"$pkgname-$pkgver-parser-aarch64.zip::https://github.com/facebook/$_pkgname/releases/download/v$pkgver/lib${_pkgname}parser-linux-arm64-v$pkgver.zip"
)
source=(
"$pkgname-$pkgver-bash-completion::https://github.com/facebook/$_pkgname/raw/v$pkgver/resources/shell/bash-completion"
"$pkgname-$pkgver-LICENSE::https://github.com/facebook/$_pkgname/raw/v$pkgver/LICENSE"
)
sha512sums=('50dd81cc39c67bc463e51a2d492119a2533548cb7e3f765e02cf9ada999397710351a1c4deadc4ffc59f4c2347b2e6ba2d4c42cbb63026ef48d50a2f2f5ee87a'
'3b8288e5dac996da44bd81b0eb1d96905c4b90ad9154f3d29d073c96890b75cd281fa03af0b77f331dbec239d341363b5f9b328bafea0d4b8d0a3e900d150f80')
sha512sums_x86_64=('1437dce3d5cace5f3709480e6a751ec992fb9e4f39ee83ab1e27c0e4e96baea62ba3969cb13bb7eff60a81e9463d497c2f535f7ec981805059bbe7d4ba4ff911'
'82b227d37fdfaf084f8d93e489ee8a573c6c9878941180108bff22c2fa13c6b2f50d7e8ffbbf821f51d2d744c612a91fdc4f22a84483a5ab7db95d1c4adcc499')
sha512sums_aarch64=('c5886ad8b4c28d1e88a397017654c105fa8b6ab9a90980072cb286e319dfe2f22e5b1def511ca41e1e5fada95328b138f0b17981f0e9b473ea98a53e220f9870'
'4a49d088f4080cf7b36e52c5eb81bf4441ecdd609e1df08ebdde6d0d321f309a74e3dfebeea8c2ebd7a0cf6c8d7e445230bb1bc16f1030d4d5ab671238dfefe1')
check() {
"$srcdir/$_pkgname/$_pkgname" --version | tee '/dev/stderr' | grep -q "version $pkgver$"
}
package() {
cd "$srcdir/"
# Binary
install -Dm755 "$_pkgname/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
# Parser library files
install -dm755 "$pkgdir/usr/lib/ocaml/${_pkgname}parser/"
install -Dm644 "lib${_pkgname}parser/include/${_pkgname}parser/"* "$pkgdir/usr/lib/ocaml/${_pkgname}parser/"
install -dm755 "$pkgdir/usr/lib/"
install -Dm644 "lib${_pkgname}parser/lib/"* "$pkgdir/usr/lib/"
# Misc files
install -Dm644 "$pkgname-$pkgver-bash-completion" "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
install -Dm644 "$pkgname-$pkgver-LICENSE" "$pkgdir/usr/share/licenses/$pkgname/MIT"
}
|