blob: f7d20dc93c0b39436cd910ce4c9a405dae9a9d0a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_binname="flow"
pkgname="${_binname}-cli"
pkgver=2.2.4
pkgrel=1
pkgdesc="A command-line interface that provides useful utilities for building Flow applications"
arch=('aarch64' 'x86_64')
url="https://docs.onflow.org/flow-cli"
_url="https://github.com/onflow/${pkgname}"
license=('Apache-2.0')
depends=('glibc')
makedepends=('go')
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${_url}/archive/refs/tags/v${pkgver}.tar.gz")
b2sums=('9d3da626a4bf0968d8239e2de164d4f525cebc47017b53023fd243cadf108935ce2244b794d49d252c6bd291cdf700a1e30e04ee5135c7d16a2102efa90c06ee')
prepare() {
cd "${srcdir}/${_pkgsrc}"
mkdir -p "build" "completions"
}
build() {
cd "${srcdir}/${_pkgsrc}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "build/${_binname}" -ldflags "\
-X ${_url#https://}/build.semver=${pkgver} \
-X ${_url#https://}/internal/command.mixpanelToken=$(grep -E '^MIXPANEL_PROJECT_TOKEN :=' Makefile | sed 's/.*= //') \
-X ${_url#https://}/internal/accounts.accountToken=$(grep -E '^ACCOUNT_TOKEN :=' Makefile | sed 's/.*= //')" \
./"cmd/${_binname}"
for _sh in bash fish zsh powershell; do
./"build/${_binname}" completion "${_sh}" > "completions/${_binname}.${_sh}"
done
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${_binname}" "${pkgdir}/usr/bin/${_binname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "completions"
install -vDm644 "${_binname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${_binname}"
install -vDm644 "${_binname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_binname}.fish"
install -vDm644 "${_binname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_binname}"
install -vDm644 "${_binname}.powershell" "${pkgdir}/usr/share/powershell/Modules/${_binname}/${_binname}.ps1"
}
|