PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Thomas Braby <thomas@mykolab.com>

_pkgbase=fltk
pkgbase=fltk-git
pkgname=fltk-git
pkgver=1.4.0.r8558.aa9f0a696
pkgrel=1
pkgdesc='Graphical user interface toolkit for X (Git version)'
arch=('x86_64')
url='http://www.fltk.org/'
license=('LGPL')
depends=('libjpeg' 'libpng' 'zlib' 'libxinerama' 'libxft' 'libxcursor')
makedepends=('git' 'cmake')
provides=('fltk')
conflicts=('fltk')
source=('fltk::git+https://github.com/fltk/fltk.git')
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgbase}"

	printf '%s.r%s.%s' \
		"$(cat VERSION)" \
		"$(git rev-list --count master)" \
		"$(git log -1 --format='%h')"
}

build() {
	cd "${srcdir}/${_pkgbase}"

	if [[ -d build ]]; then
		rm -rf build
	fi
	mkdir build && cd build

	cmake .. \
		-DCMAKE_INSTALL_PREFIX='/usr' \
		-DCMAKE_INSTALL_LIBDIR='lib' \
		-DCMAKE_BUILD_TYPE='Release' \
		-DOPTION_BUILD_EXAMPLES=0

	make
}

package() {
	cd "${srcdir}/${_pkgbase}/build"
	make DESTDIR="${pkgdir}/" install
}