blob: 806aa61a3b3d5c6024538435e55e49bef0690194 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=('fluent-icon-theme-git' 'fluent-cursor-theme-git')
pkgbase=fluent-icon-theme-git
pkgver=2024.02.25.r8.gd56a03ec
pkgrel=1
pkgdesc="A Fluent design icon theme"
arch=('any')
url="https://github.com/vinceliuice/Fluent-icon-theme"
license=('GPL-3.0-or-later')
depends=('hicolor-icon-theme' 'gtk-update-icon-cache')
makedepends=('git')
options=('!strip')
source=('git+https://github.com/vinceliuice/Fluent-icon-theme.git')
sha256sums=('SKIP')
pkgver() {
cd Fluent-icon-theme
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd Fluent-icon-theme
# Disable running gtk-update-icon-cache
sed -i '/gtk-update-icon-cache/d' install.sh
}
package_fluent-icon-theme-git() {
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
cd Fluent-icon-theme
install -d "$pkgdir/usr/share/icons"
./install.sh -a -d "$pkgdir/usr/share/icons"
}
package_fluent-cursor-theme-git() {
pkgdesc="An x-cursor theme inspired by Qogir theme and based on capitaine-cursors."
depends=('libxcursor')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
cd Fluent-icon-theme/cursors
install -d "$pkgdir/usr/share/icons"
cp -r dist "$pkgdir/usr/share/icons/Fluent-cursors"
cp -r dist-dark "$pkgdir/usr/share/icons/Fluent-dark-cursors"
}
|