blob: 0aaf2dd3c0a3c5c07179965ea3956c5a46b8def9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Maintainer: The one with the braid <info@braid.business>
# thanks to celogeek, sseneca, dr460nf1r3, dr460nf1r3 and AverytheFurry for pointing out multiple things
pkgname=fluffychat
_name=${pkgname}
_appid=chat.fluffy.fluffychat
pkgver=1.20.0
pkgrel=6
pkgdesc="Open. Nonprofit. Cute. Easy to use (matrix) messenger. Secure and decentralized."
# Flutter officially supports amd64 and AArch64
arch=('x86_64' 'aarch64')
url="https://fluffychat.im/"
license=('AGPL3')
depends=(
'gtk3'
'jsoncpp'
# flutter_secure_storage
'libsecret'
# path_provider
'xdg-user-dirs'
# for e2ee
'libolm'
# flutter_file_picker - see https://github.com/miguelpruivo/flutter_file_picker/blob/master/lib/src/linux/file_picker_linux.dart#L115
'zenity'
# sqlite encryption
'openssl'
)
makedepends=(
# the Flutter tool
'flutter-tool'
# the Flutter linux files
'flutter-target-linux'
# used for packaging
'cmake'
)
# prevent conflicts with binary or release packages
provides=("$_name")
conflicts=("$_name")
source=(
"fluffychat-v${pkgver}.tar.gz::https://github.com/krille-chan/fluffychat/archive/refs/tags/v${pkgver}.tar.gz"
)
sha256sums=('c8a0462a1729fc9feb7213af2266cc230dc61fad589b2507cdb4e8144a5fef19')
# ensure we have the proper Dart architecture name for the current CARCH
case "${CARCH}" in
"x86_64")
export _dartarch="x64"
;;
"aarch64")
export _dartarch="arm64"
;;
esac
prepare() {
# override pub cache
export PUB_CACHE="${srcdir}/pub_cache"
# enter the source directory
cd "${srcdir}/${_name}-${pkgver}"
# download dart dependencies without lockfile update or retry with
flutter pub get --enforce-lockfile || flutter pub get
}
build() {
# override pub cache
export PUB_CACHE="${srcdir}/pub_cache"
# enter the source directory
cd "${srcdir}/${_name}-${pkgver}"
# build in release mode without running pub
flutter build linux --no-pub --release
}
package() {
# enter the output directory of the Flutter build
cd "${srcdir}/${_name}-${pkgver}/build/linux/$_dartarch/release"
# configure the installation directory using cmake
cmake -DCMAKE_INSTALL_PREFIX=${pkgdir}/usr/lib/${_name} .
# install the Flutter project using cmake
cmake -P cmake_install.cmake
# link executable into PATH
install -dm755 "${pkgdir}/usr/bin"
ln -s "/usr/lib/${_name}/${_name}" "${pkgdir}/usr/bin/${_name}"
# install desktop file, metainfo, license and icons
install -Dm 644 "${srcdir}/${_name}-${pkgver}/assets/favicon.png" "${pkgdir}/usr/share/pixmaps/${_appid}.png"
install -Dm 644 "${srcdir}/${_name}-${pkgver}/assets/favicon.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${_appid}.png"
install -Dm644 "${srcdir}/${_name}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${_name}/LICENSE"
install -dm 755 "${pkgdir}/usr/share/applications"
cat > ${pkgdir}/usr/share/applications/${_appid}.desktop << EOF
[Desktop Entry]
Type=Application
Version=${pkgver}
Name=FluffyChat
Comment=${pkgdesc}
Exec=${_name}
Icon=${_appid}
SingleMainWindow=true
StartupWMClass=${_appid}
Terminal=false
StartupNotify=false
Categories=Network;InstantMessaging;Chat;MatrixClient
X-Purism-FormFactor=Workstation;Mobile;
EOF
}
# vim: set sw=2 ts=2 et:
|