blob: 71043d71f0bdfd84b69f7e7d333f423c9bae07a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: garionion <garionion at entr0py.de>
# Contributor: kescherAUR
pkgname=fluffychat-bin
_pkgname=fluffychat
pkgver=0.36.0
pkgrel=1
pkgdesc="Chat with your friends"
arch=('x86_64' 'aarch64')
url="https://fluffychat.im/"
license=('AGPL3')
depends=('libolm' 'xdg-user-dirs' 'gtk3' 'jsoncpp')
makedepends=('unzip')
provides=("$_pkgname")
conflicts=("$_pkgname")
source_x86_64=("fluffychat-v${pkgver}_x86_64.tar.gz::https://gitlab.com/api/v4/projects/16112282/packages/generic/fluffychat/${pkgver}/fluffychat-linux-x86.tar.gz")
source_aarch64=("fluffychat-v${pkgver}_aarch64.tar.gz::https://gitlab.com/api/v4/projects/16112282/packages/generic/fluffychat/${pkgver}/fluffychat-linux-arm64.tar.gz")
sha256sums_x86_64=('d8ce132cda428cb2dd7bff75712e12b301830d986d5f812dc8e7374a5241f2a6')
sha256sums_aarch64=('6d084281b4582ae56eb913fa5804db4d211b11ad954443d0631750c67d83a111')
package() {
# install
install -dm755 ${pkgdir}/opt/${_pkgname}/
mv ${_pkgname} ${pkgdir}/opt/${_pkgname}/
mv data ${pkgdir}/opt/${_pkgname}/
mv lib ${pkgdir}/opt/${_pkgname}/
# link
install -dm755 ${pkgdir}/usr/bin
ln -s /opt/${_pkgname}/${_pkgname} ${pkgdir}/usr/bin/${_pkgname}
# icon
install -Dm 644 ${pkgdir}/opt/${_pkgname}/data/flutter_assets/assets/favicon.png ${pkgdir}/usr/share/pixmaps/${_pkgname}.png
# desktop entry
install -dm 755 "${pkgdir}/usr/share/applications"
cat > ${pkgdir}/usr/share/applications/${_pkgname}.desktop << EOF
[Desktop Entry]
Type=Application
Version=${pkgver}
Name=FluffyChat
Comment=Matrix Client. Chat with your friends
Exec=/opt/${_pkgname}/${_pkgname}
Icon=${_pkgname}
Terminal=false
EOF
}
# vim: set sw=2 ts=2 et:
|