blob: 9af65a1b6e95dbb464be0744c42537d3769d10e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
_name=Fluida.lv2
_plugin_uri="https://github.com/brummer10/$_name"
pkgname=${_name,,}
pkgver=0.9.3
pkgrel=1
pkgdesc='An LV2 plugin which wraps the fluidsynth SF2 soundfont player'
arch=(x86_64 aarch64)
url="https://github.com/brummer10/$_name"
license=(GPL2 MIT)
depends=(cairo gcc-libs glibc libx11)
makedepends=(fluidsynth lv2 xxd)
checkdepends=(lv2lint)
optdepends=('lv2-host: for loading the LV2 format plugin')
groups=(lv2-plugins pro-audio)
source=("https://github.com/brummer10/Fluida.lv2/releases/download/v$pkgver/${_name}-v$pkgver-src.tar.xz")
sha256sums=('b777dbbbc6438387faaddba604fa4385f3fb92104d0c0c36e0317921e1362f30')
build() {
cd $_name-v$pkgver
make
}
check() {
cd $_name-v$pkgver
lv2lint -s '_Z*' -Mpack -I bin/$_name "$_plugin_uri"
}
package() {
depends+=(libfluidsynth.so)
cd $_name-v$pkgver
make DESTDIR="$pkgdir" PREFIX=/usr install
install -vDm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
install -vDm 644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
install -vDm 644 Fluida/libscala-file/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE-libscala-file
}
|