summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 457ed697f537828f2c50d07a7b1866290eb831bc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Maintainer: Malte Linke <me@parzival.space>
# Contributor: Vladislav <your@email.com>

pkgname=fluorine-manager-bin
pkgdesc='A native Linux mod manager for Bethesda and other games, built on MO2'
pkgver=0.4.1 # renovate: datasource=github-tags depName=SulfurNitride/Fluorine-Manager versioning=semver
pkgrel=1
arch=('x86_64')
url='https://github.com/SulfurNitride/Fluorine-Manager'
license=('GPL-3.0-or-later')
provides=('fluorine-manager')
conflicts=('fluorine-manager')
depends=('mesa' 'gcc-libs' 'hicolor-icon-theme')
optdepends=('steam: allows the usage of Proton')
options=(!strip)

_releaseArchive="fluorine-manager-${pkgver}.tar.gz"
source=("${_releaseArchive}::https://github.com/SulfurNitride/Fluorine-Manager/releases/download/v${pkgver}/${_releaseArchive}"
        "LICENSE::https://raw.githubusercontent.com/SulfurNitride/Fluorine-Manager/refs/tags/v${pkgver}/LICENSE.txt"
        "disable-desktop-sync.patch")
sha256sums=('df4a734363aff2e5eaf0dc05a68c87f3281293ae07838f68553cd309c52b4585'
            '8ceb4b9ee5adedde47b31e975c1d90c73ad27b6b165a1dcd80c7c545eb65b903'
            'f76a7e83ed721beccb23a36241f40485352045ac82632a594f319504a359bfec')
noextract=("${_releaseArchive}")

prepare() {
  bsdtar -xf "${_releaseArchive}" -C "${srcdir}"

  # remove the post-installation sync to the user home from the wrapper script
  patch -d "${srcdir}/fluorine-manager" -tNp0 -i ../disable-desktop-sync.patch
}

package() {
  # install archive files
  install -dm755 "${pkgdir}/opt/fluorine-manager"
  cp -a "${srcdir}/fluorine-manager/." "${pkgdir}/opt/fluorine-manager"

  # link to bin
  install -d "${pkgdir}/usr/bin"
  ln -s "/opt/fluorine-manager/fluorine-manager" "${pkgdir}/usr/bin/fluorine-manager"

  # install desktop icon
  install -Dm644 "${srcdir}/fluorine-manager/icons/com.fluorine.manager.desktop" "${pkgdir}/usr/share/applications/com.fluorine.manager.desktop"
  install -Dm644 "${srcdir}/fluorine-manager/icons/com.fluorine.manager.png" "${pkgdir}/usr/share/icons/hicolor/256x256/apps/com.fluorine.manager.png"

  # install license file
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}