blob: 686104a77da5c74b96bde2cb7c8cc41f3b3e22ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Limao Luo <luolimao+AUR@gmail.com>
# Contributor: Devin Cofer <ranguvar@archlinux.us>
# Contributor: Cainã Costa <sryche@archlinux-br.org>
# Contributor: Patrick Bartels <p4ddy.b@gmail.com>
pkgname=fluxbox-git
pkgdesc="Lightweight stacking WM with tabbing, dockapps, etc."
pkgver=1.3.5.46.gf3e82ca
pkgrel=1
arch=(i686 x86_64)
url=http://www.fluxbox.org/
license=(MIT)
depends=(fribidi imlib2 libxft libxinerama libxpm libxrandr)
makedepends=(git)
optdepends=('xorg-xmessage: for using the fbsetbg and fluxbox-generate_menu utilities')
provides=(${pkgname%-*}=$pkgver)
conflicts=(${pkgname%-*})
options=(!libtool)
source=($pkgname::git://git.fluxbox.org/${pkgname%-*}.git
$pkgname.desktop)
sha256sums=('SKIP'
'32ed3d444c938a3778520a641d5e0196a0fdf2984390d69a6546f8b86805c841')
sha512sums=('SKIP'
'4c46bb22745849982b2e1ea02cc84f77bf81eeac827b10574eabcb5f2375805fe8b204a58aed15555b2477b1b9cc3f9e0aa4575a92ad9315495735a8e7ba40d1')
pkgver() {
cd $pkgname/
git describe | sed 's|Release-||;s|[_-]|.|g'
}
build() {
cd $pkgname/
autoreconf -fi
./configure --prefix=/usr --enable-xft --enable-xinerama --enable-imlib2 --enable-nls
make
}
package() {
cd $pkgname/
make DESTDIR="$pkgdir" install
install -Dm644 ../$pkgname.desktop "$pkgdir"/usr/share/xsessions/${pkgname%-*}.desktop
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
|