blob: 45ba3de98251c2d74e58e9aeded3191ffc3d4623 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: [none]
# Contributor: dreieck
# Controbutor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
_pkgname='folks'
_pkgfeature='telepathy'
pkgname="${_pkgname}-${_pkgfeature}-git"
pkgver=0.15.9.1+r3042.20240323.1c3a0baa
pkgrel=1
pkgdesc="Library to aggregates people into metacontacts. Variant of 'folks' with telepathy backend compiled in. Latest git checkout."
arch=(
'x86_64'
'i686'
)
url="https://wiki.gnome.org/Projects/Folks"
license=(LGPL2.1)
depends=(
'dconf'
'gcc-libs'
'glib2'
'glibc'
'evolution-data-server'
'libgee'
'libxml2'
'readline'
'telepathy-glib'
)
makedepends=(
'git'
'gobject-introspection'
'gtk-doc'
'meson'
'python-dbusmock'
'vala'
)
provides=(
"${_pkgname}=${pkgver}"
"${_pkgname}-${_pkgfeature}=${pkgver}"
"${_pkgname}-git=${pkgver}"
"libfolks.so"
"libfolks-dummy.so"
"libfolks-eds.so"
"libfolks-telepathy.so"
)
conflicts=(
"${_pkgname}"
"${_pkgname}-${_pkgfeature}"
"libfolks.so"
"libfolks-dummy.so"
"libfolks-eds.so"
"libfolks-telepathy.so"
)
source=("${_pkgname}::git+https://gitlab.gnome.org/GNOME/folks.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
_ver="$(git describe --tags | sed 's|^v||' | sed 's|-[^-]*$||' | tr '-' '.')"
_rev="$(git rev-list --count HEAD)"
_date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
_hash="$(git rev-parse --short HEAD)"
if [ -z "${_ver}" ]; then
error "Version could not be determined."
return 1
else
printf '%s' "${_ver}+r${_rev}.${_date}.${_hash}"
fi
}
build() {
cd "${srcdir}"
local meson_args=(
-D b_lto=false # LTO copies some GType constructors
-D docs=true
-D telepathy_backend=true
)
arch-meson "${_pkgname}" build "${meson_args[@]}"
meson compile -C build
}
# check() {
# cd "${srcdir}"
#
# meson test -C build --print-errorlogs -t 4
# }
package() {
cd "${srcdir}"
meson install -C build --destdir "${pkgdir}"
}
# vim:set sw=2 et:
|