summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 144bd4c0532ed3080988cf674f42cbe12717eb0e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer:  Caleb Maclennan <caleb@alerque.com>
# Contributor: Joeny Ang <ang.joeny@gmail.com>
# Contributor: Zaler <zldream1011@gmail.com>
# Contributor: joni <kljohann@gmail.com>
# Contributor: Dies <JerryCasiano@gmail.com>

pkgname=font-manager-git
_branch=master
pkgver=0.7.5.r0.gdaf9d39
pkgrel=1
pkgdesc='A simple font management application for GTK+ Desktop Environments'
url='http://fontmanager.github.io'
arch=('i686' 'x86_64')
license=('GPL')
depends=('libxml2' 'sqlite')
optdepends=('file-roller')
makedepends=('git' 'yelp-tools' 'gobject-introspection' 'vala' 'meson' 'ninja')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git://github.com/FontManager/master.git#branch=$_branch")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$pkgname"

  meson --prefix /usr --buildtype=debugoptimized build_dir
  ninja -v -C build_dir
}

package() {
  cd "$pkgname"
  DESTDIR="$pkgdir" ninja -C build_dir install
}