blob: 3a7bd7d5d324aa37bbda6099f7d97054a1658bee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
pkgname=fontforge-git
pkgver=20190801.r246.gf28b9e6b5
pkgrel=1
epoch=1
pkgdesc='Full-featured outline and bitmap font editor.'
url='https://fontforge.github.io/'
arch=('i686' 'x86_64')
license=('GPL3' 'BSD')
depends=('libtool' 'pango' 'giflib' 'libtiff' 'libxml2' 'libspiro' 'python'
'potrace' 'woff2' 'gtk3' 'libuninameslist')
makedepends=('git' 'cmake' 'ninja')
provides=('fontforge')
conflicts=('fontforge')
source=('git+https://github.com/fontforge/fontforge.git')
sha256sums=('SKIP')
pkgver() {
cd fontforge
git describe | sed 's/-/.r/; s/-/./'
}
build() {
cd fontforge
rm -rf build
mkdir build
cd build
cmake \
-G"Ninja" \
-D"CMAKE_BUILD_TYPE:STRING=Release" \
-D"CMAKE_INSTALL_PREFIX:PATH=/usr" \
-D"ENABLE_MAINTAINER_TOOLS:BOOL=TRUE" \
-D"ENABLE_FONTFORGE_EXTRAS:BOOL=TRUE" \
-D"UNIX:BOOL=TRUE" \
..
ninja
}
package() {
cd fontforge/build
DESTDIR="$pkgdir" ninja install
install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
# Remove docs if required. This is roughly 10MiB
#rm -rf "$pkgdir/usr/share/doc/fontforge"
}
|