PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=fontship
pkgver=0.8.2
pkgrel=3
pkgdesc='A font development toolkit and collaborative work flow'
arch=(any)
url="https://github.com/theleagueof/$pkgname"
license=(AGPL4)
depends=(diffutils
         entr
         font-v
         gftools
         git
         jq
         libarchive
         libgit2
         make
         psautohint
         python
         python-babelfont
         python-brotli # fonttools optdepends
         python-cffsubr # ufo2ft optdepends
         python-fontmake
         python-fonttools
         python-fs # fonttools optdepends
         python-lxml # fonttools optdepends
         python-pcpp
         python-skia-pathops # ufo2ft optdepends
         'python-ufo2ft>=2.19.1'
         python-ufonormalizer
         python-unicodedata2 # fonttools optdepends
         python-vttlib
         python-zopfli # fonttools optdepends
         'sfd2ufo>=1.0.7'
         sfdnormalize
         sfnt2woff-zopfli
         ttfautohint
         woff2
         zsh)
makedepends=(cargo
             rust)
_archive="$pkgname-$pkgver"
source=("$url/releases/download/v$pkgver/$_archive.tar.xz")
sha256sums=('710687f2189a67f786c5e8dea389c8edb4edb4026aeca6ce306638d1bbc5a6ce')

prepare() {
	cd "$_archive"
	cargo fetch --locked
}

build() {
	cd "$_archive"
	./configure --prefix="/usr"
	make
}

check() {
	cd "$_archive"
	make check
}

package() {
	cd "$_archive"
	make DESTDIR="$pkgdir" install
}