blob: fcfe3938e3d88bab5af050c0e4347007e57d4f9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
pkgname=forgecode-nu
pkgver=0.1.0
pkgrel=1
pkgdesc='Nushell plugin for Forge colon-command workflows'
arch=('any')
url='https://github.com/OneNoted/forgecode.nu'
license=('Apache-2.0')
depends=('nushell')
optdepends=(
'forge: required Forge CLI backend'
)
conflicts=('forgecode-nu-git')
source=(
"https://github.com/OneNoted/forgecode.nu/archive/refs/tags/v${pkgver}.tar.gz"
)
sha256sums=('d60f527516882a148d305e12a451b8448187712cbee58aa65ad901ae34834993')
package() {
cd "${srcdir}/forgecode.nu-${pkgver}"
install -dm755 \
"${pkgdir}/usr/share/nushell/vendor/autoload" \
"${pkgdir}/usr/share/forgecode.nu/lib/actions" \
"${pkgdir}/usr/share/doc/${pkgname}" \
"${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm644 forgecode.nu \
"${pkgdir}/usr/share/forgecode.nu/forgecode.nu"
local file
for file in lib/*.nu; do
install -Dm644 "$file" "${pkgdir}/usr/share/forgecode.nu/${file}"
done
for file in lib/actions/*.nu; do
install -Dm644 "$file" "${pkgdir}/usr/share/forgecode.nu/${file}"
done
cat > "${pkgdir}/usr/share/nushell/vendor/autoload/forgecode.nu" <<'SHIM'
use /usr/share/forgecode.nu/forgecode.nu *
SHIM
install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
local doc
for doc in docs/*.md; do
install -Dm644 "$doc" "${pkgdir}/usr/share/doc/${pkgname}/$(basename "$doc")"
done
}
|