blob: 2b4ccc518bd526a92635ce43fe0ffd36439d21d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=fotoxx
pkgver=19.13
pkgrel=1
pkgdesc="A program for improving image files made with a digital camera, stable version"
url="http://www.kornelix.net/fotoxx/fotoxx.html"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('libraw' 'gtk3' 'libchamplain' 'perl-image-exiftool>=0.8.6' 'xdg-utils')
optdepends=('rawtherapee: for raw image processing'
'dvd+rw-tools: for burning CDs,DVDs or BlueRays'
'hugin: for panorama photos')
source=("http://www.kornelix.net/downloads/downloads/$pkgname-$pkgver.tar.gz")
sha512sums=('d95e941783334277935c0839359a0d4a4c8f8ff717c6d92a49b1775013a582200784a32dedbe3742a8ccc0370f94d477adade7b789a650b076ae8dcdac1617ab')
prepare() {
cd $pkgname
sed -i 's+libchamplain+champlain+g' Makefile
chmod o+r images/color-mode.jpg
}
build() {
cd $pkgname
make PREFIX=/usr
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" PREFIX=/usr ICONDIR=/usr/share/pixmaps install
rm -r "$pkgdir"/usr/share/appdata
chmod o+r "$pkgdir"/usr/share/fotoxx/images/show-RGB.jpg
sed -i 's+/usr/share/fotoxx/icons/++' "$pkgdir"/usr/share/applications/$pkgname.desktop
}
|