blob: 64906aee4d21d10c55175a00cb3ac6ec56749062 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=fotoxx
pkgver=19.15
pkgrel=1
pkgdesc="A program for improving image files made with a digital camera, stable version"
url="http://www.kornelix.net/fotoxx/fotoxx.html"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('libraw' 'gtk3' 'libchamplain' 'perl-image-exiftool>=0.8.6' 'xdg-utils')
optdepends=('rawtherapee: for raw image processing'
'dvd+rw-tools: for burning CDs,DVDs or BlueRays'
'hugin: for panorama photos')
source=("http://www.kornelix.net/downloads/downloads/$pkgname-$pkgver.tar.gz")
sha512sums=('8d4cd6e1830513f93029174dae37d19ec106b490b5f23adfaa923d48886a4585fc94b69a0ac3ed73cf9c2a12cbadbcd8700a696fbf13a853868cc09600cc39fa')
prepare() {
cd $pkgname
sed -i 's+libchamplain+champlain+g' Makefile
chmod o+r images/color-mode.jpg
}
build() {
cd $pkgname
make PREFIX=/usr
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" PREFIX=/usr ICONDIR=/usr/share/pixmaps install
rm -r "$pkgdir"/usr/share/appdata
chmod o+r "$pkgdir"/usr/share/fotoxx/images/show-RGB.jpg
sed -i 's+/usr/share/fotoxx/icons/++' "$pkgdir"/usr/share/applications/$pkgname.desktop
}
|