blob: 12ea181bcffab208c76051b11fdc73aca174e267 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=fowl
pkgver=25.10.0
pkgrel=2
pkgdesc='Forward over Wormhole: streams over magic-wormhole Dilation connections'
arch=(any)
url="https://pypi.org/project/$pkgname"
license=(MIT)
_pydeps=(attrs
click
humanize
msgpack
rich
twisted)
depends=(magic-wormhole
python
"${_pydeps[@]/#/python-}")
makedepends=(python-{build,installer,wheel}
python-hatchling)
checkdepends=(python-hypothesis
python-magic-wormhole-mailbox-server
python-pytest
python-pytest-twisted)
_archive="${pkgname/-/_}-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
sha256sums=('f4f67f669616bb20ccba67ee7c8207931674f34daefd6c2af91a0392beb0fe8c')
build() {
cd "$_archive"
python -m build -wn
}
check() {
cd "$_archive"
export PYTHONPATH="$PWD/src"
pytest
}
package() {
cd "$_archive"
python -m installer -d "$pkgdir" dist/*.whl
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.rst
}
|