blob: 3b521e7a9275120aea0dbe16817fad97593f39c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Muflone http://www.muflone.com/contacts/english/
# Contributor: TDY <tdy@archlinux.info>
pkgname=foxitreader
epoch=1
pkgver=1.1.0.0225
_pkgver=1.10.0225
_pkgrev=205262
pkgrel=2
pkgdesc="A fast, secure and complete PDF viewer"
arch=('i686' 'x86_64')
url="http://www.foxitsoftware.com/Secure_PDF_Reader/"
license=('custom:EULA')
makedepends=('qt-installer-framework' 'qt5-tools' 'p7zip')
depends=('desktop-file-utils')
install="${pkgname}.install"
source=("https://www.foxitsoftware.com/products/pdf-reader/eula.html"
"${pkgname}.patch")
source_i686=("http://cdn01.foxitsoftware.com/pub/foxit/reader/desktop/linux/1.x/${pkgver%.*.*}/en_us/FoxitReader${_pkgver}_Server_x86_enu_Setup.run.tar.gz")
source_x86_64=("http://cdn01.foxitsoftware.com/pub/foxit/reader/desktop/linux/1.x/${pkgver%.*.*}/en_us/FoxitReader${_pkgver}_Server_x64_enu_Setup.run.tar.gz")
sha256sums=('a5be3dc1cf27536de2c0fb5a0d640db349be32f48547b3cc56dcb5791fb278be'
'2111205034f47ba57e1fa328e3f190f9f33c8680927cc9a0492ca98cff0107b3')
sha256sums_i686=('16984a9b52537dcb57c2304441fca3a906a8bd7271f1f4919fcdc8a5dbdf9fc8')
sha256sums_x86_64=('2967571a4844ab834e03f9d63ee89c3df027ac16c8ae25e6f7affee70654c1cf')
build() {
# Clean installer dir
if [ -d "${pkgname}-installer" ]
then
rm -rf "${pkgname}-installer"
fi
# Decompress .run installer
if [ "${CARCH}" = 'x86_64' ]
then
_file_run="FoxitReader.enu.setup.${pkgver}(r${_pkgrev}).x64.run"
else
_file_run="FoxitReader.enu.setup.${pkgver}(r${_pkgrev}).x86.run"
fi
devtool --dump "${pkgname}-installer" "${_file_run}"
}
package() {
cd "${pkgname}-installer/metadata/Install Foxit Reader"
# Decompress files
install -m 755 -d "${pkgdir}/usr/lib/${pkgname}"
for file in *.7z
do
7z x -o"${pkgdir}/usr/lib/${pkgname}" ${file} > /dev/null
done
# Apply final patches
cd "${pkgdir}"
patch -p1 -i "${srcdir}/${pkgname}.patch"
# Remove useless files
cd "${pkgdir}/usr/lib/${pkgname}"
rm "lib/.directory" "Activation" "Activation.desktop" "Activation.sh" \
"countinstalltion" "countinstalltion.sh" \
"installUpdate" "ldlibrarypath.sh" \
"maintenancetool.sh" "Uninstall.desktop" \
"Update.desktop" "updater" "updater.sh" \
"manual/en_us/FoxitReader1.0_QuickGuide_Linux.pdf" \
"manual/en_us/FoxitReader1.0_QuickGuide_OSX.pdf" \
"manual/en_us/FoxitReader1.1_QuickGuide_OSX.pdf"
# Install icon and desktop files
install -m 755 -d "${pkgdir}/usr/share/pixmaps"
install -m 644 "images/FoxitReader.png" \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -m 755 -d "${pkgdir}/usr/share/applications"
install -m 755 "FoxitReader.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Install license file
install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/eula.html"
# Install launcher script
cd "${pkgdir}"
install -m 755 -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/${pkgname}/FoxitReader.sh" "${pkgdir}/usr/bin/${pkgname}"
}
|