blob: 4bc7d3d96d1005b6a10e7af66ef9b0b3efa40e7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Maintainer: Muflone http://www.muflone.com/contacts/english/
# Contributor: Stephen Zhang <zsrkmyn at gmail dot com>
# Contributor: TDY <tdy@archlinux.info>
pkgname=foxitreader
pkgver=2.4.1.0609
_foxitrevision=r08f07f8
pkgrel=8
pkgdesc="A fast, secure and complete PDF viewer"
arch=('x86_64')
url="https://www.foxitsoftware.com/products/pdf-reader/"
license=('custom:EULA')
depends=('libsecret')
makedepends=('p7zip')
source=("http://cdn09.foxitsoftware.com/pub/foxit/reader/desktop/linux/2.x/${pkgver%.*.*}/en_us/FoxitReader${pkgver}_Server_x64_enu_Setup.run.tar.gz"
"https://www.foxitsoftware.com/products/pdf-reader/eula.html"
"${pkgname}.patch"
"${pkgname}-excluded_files-x86_64")
sha256sums=('d8093dd3b3aeb4e788cbdff5f9d05d7557eb440810f6da6bdc4e23447d3a27ba'
'c1485614de2b8087d14ab2d7b10e51faaaaf83a96f8bce6a0e1791effadf6079'
'd85bfa4b293927975182aa6b1582ac064c5732711e5678d5f1ec35e65c78e6d1'
'87932852ae1ce12bc8e9e7a7d3cdf2f8fdcdf8cf5f27871f1297b920223c4aa7')
build() {
local _file
local _line
local _position
# Clean installer dir
if [ -d "${pkgname}-installer" ]
then
rm -rf "${pkgname}-installer"
fi
mkdir "${pkgname}-installer"
# Decompress .run installer
_file="FoxitReader.enu.setup.${pkgver}(${_foxitrevision}).x64.run"
LANG=C grep --only-matching --byte-offset --binary \
--text $'7z\xBC\xAF\x27\x1C' "${_file}" | cut -f1 -d: |
while read _position
do
dd if="${_file}" \
bs=1M iflag=skip_bytes status=none skip=${_position} \
of="${pkgname}-installer/bin-${_position}.7z"
done
# Clean build dir
if [ -d "${pkgname}-build" ]
then
rm -rf "${pkgname}-build"
fi
# Decompress 7z files (some files are damaged during the extraction)
cd "${pkgname}-installer"
install -m 755 -d "${srcdir}/${pkgname}-build"
for _file in *.7z
do
7z -bd -bb0 -y x -o"${srcdir}/${pkgname}-build" ${_file} 1>/dev/null 2>&1 || true
done
# Apply final patches
cd "${srcdir}/${pkgname}-build"
patch -p4 --no-backup-if-mismatch -i "${srcdir}/${pkgname}.patch"
# Remove unneeded files
rm "Activation" "Activation.desktop" "Activation.sh" \
"countinstalltion" "countinstalltion.sh" \
"installUpdate" "ldlibrarypath.sh" \
"maintenancetool.sh" "Uninstall.desktop" \
"Update.desktop" "updater" "updater.sh"
find -type d -name ".svn" -exec rm -rf {} +
find -type f -name ".directory" -exec rm -rf {} +
find -type f -name "*~" -exec rm {} +
# Remove excluded files
while IFS='' read -r _line
do
if [ "${_line::2}" = "# " ]
then
echo " -> Removing excluded files from ${_line:2}..."
elif [ -n "${_line}" -a "${_line::1}" != "#" ]
then
rm "${srcdir}/${pkgname}-build/${_line}"
fi
done < "${srcdir}/${pkgname}-excluded_files-$CARCH"
}
package() {
install -m 755 -d "${pkgdir}/usr/lib/${pkgname}"
cd "${srcdir}/${pkgname}-build"
cp -r * "${pkgdir}/usr/lib/${pkgname}"
# Install icon and desktop files
install -m 755 -d "${pkgdir}/usr/share/pixmaps"
install -m 644 "images/FoxitReader.png" \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -m 755 -d "${pkgdir}/usr/share/applications"
install -m 755 "FoxitReader.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
rm FoxitReader.desktop
# Install license file
install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/eula.html"
# Install launcher script
cd "${pkgdir}"
install -m 755 -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/${pkgname}/FoxitReader.sh" "${pkgdir}/usr/bin/${pkgname}"
}
|