PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Philip Goto <philip.goto@gmail.com>

_pkgname=fragments
pkgname=$_pkgname-git
pkgver=1.1.r36.gf8e71b9
pkgrel=1
pkgdesc="A GTK3 BitTorrent client following the GNOME Human Interface Guidelines"
arch=(i686 x86_64 armv6h armv7h)
url="https://github.com/haecker-felix/Fragments"
license=(GPL3)
depends=(curl
         gtk3
         libb64
         libevent
         libnatpmp
         miniupnpc)
makedepends=(git
             gobject-introspection
             libdazzle
             libhandy
             meson
             vala)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/haecker-felix/Fragments.git")
md5sums=(SKIP)

prepare() {
    cd Fragments
    git submodule update --init --recursive
}

pkgver() {
    cd Fragments
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    rm -rf build
    arch-meson Fragments build
    ninja -v -C build
}

package() {
    DESTDIR="$pkgdir/" ninja -C build install
}