blob: d0f520e188320e3f1b0f3b2b25edce059868adda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgname=frameworkintegration-git
pkgver=r234.3ebe689
pkgrel=1
pkgdesc='Framework providing components to allow applications to integrate with a KDE Workspace'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/frameworks/frameworkintegration'
license=('LGPL')
depends=('kio-git' 'noto-fonts' 'libxcursor')
makedepends=('extra-cmake-modules-git' 'git')
groups=('kf5')
conflicts=(frameworkintegration)
provides=(frameworkintegration)
source=('git://anongit.kde.org/frameworkintegration.git')
md5sums=('SKIP')
pkgver() {
cd frameworkintegration
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../frameworkintegration \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|