blob: e11ee20304424ece540c8a32261fc88f00d7b5ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Sven Karsten Greiner <sven@sammyshp.de>
# Contributor: Vladimir Cerny <blackvladimir@gmail.com>
pkgname=free42
pkgver=2.5.14
pkgrel=1
pkgdesc="A complete re-implementation of the HP-42S calculator and the HP-82240 printer"
arch=('i686' 'x86_64')
url="http://thomasokken.com/free42/"
license=('GPL')
depends=('gtk3')
optdepends=('free42-skins: Additional skins')
source=("http://thomasokken.com/free42/upstream/$pkgname-nologo-$pkgver.tgz"
"0001_system-skins.patch"
"free42.desktop")
md5sums=('dbe231fc32fea4067d8654c6203ff890'
'8c0522e3efa3c7fd54985af456b689b7'
'9e1af9bfd8ce5eb2ad107f63ea446a55')
prepare() {
cd "$srcdir/$pkgname-nologo-$pkgver/"
# Read skins from system-wide directory (see package "free42-skins")
# This patch can be removed if you want the original upstream version
patch -Np1 -i "$srcdir/0001_system-skins.patch"
}
build() {
cd "$srcdir/$pkgname-nologo-$pkgver/gtk"
# build both bin and dec version
make cleaner
make SKIN_SYS_DIR="/usr/share/free42/skins"
make clean
make BCD_MATH=1 SKIN_SYS_DIR="/usr/share/free42/skins"
}
package() {
cd "$srcdir/$pkgname-nologo-$pkgver/gtk"
install -Dm755 free42bin "$pkgdir/usr/bin/free42bin"
install -Dm755 free42dec "$pkgdir/usr/bin/free42dec"
install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README_GTK"
install -Dm644 ../README "$pkgdir/usr/share/doc/$pkgname/README"
install -Dm644 icon-48x48.xpm "$pkgdir/usr/share/icons/hicolor/48x48/apps/free42.xpm"
install -Dm644 icon-128x128.xpm "$pkgdir/usr/share/icons/hicolor/128x128/apps/free42.xpm"
ln -s /usr/bin/free42dec "$pkgdir/usr/bin/free42"
cd ../skins
for _f in Ehrling42sl.* Standard.* README.txt; do
install -Dm644 $_f "$pkgdir/usr/share/$pkgname/skins/$_f"
done
install -Dm644 "$srcdir/free42.desktop" "$pkgdir/usr/share/applications/com.thomasokken.free42.desktop"
}
# vim:set ts=2 sw=2 et:
|