blob: bba20b04785c6baf340460983062e64e8805fcc4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Igor Moura <imp2@cin.ufpe.br>
pkgname=freecad-appimage
pkgver=0.18_16110
pkgrel=1
pkgdesc="A general purpose 3D CAD modeler (binary AppImage version)"
arch=('x86_64')
url='http://www.freecadweb.org/'
license=('LGPL')
provides=('freecad')
conflicts=('freecad')
source=("https://github.com/FreeCAD/FreeCAD/releases/download/0.18.1/FreeCAD_${pkgver//_/-}-Linux-Conda_Py3Qt5_glibc2.12-${arch}.AppImage"
freecad.desktop.patch
freecad.sh)
sha256sums=('a22812f9ad66f22cae843998994f23d54191d623b4a7c7f05cc7fa0293e69f63'
'7e3755f477d24f869408ac67ae75379b727464cc646b0a69ce86afe6e3ca9fef'
'9bfca97e1e633601ddfbd74f32501050f50378cfd6b30f5bf91d978e7ce33436')
options=(!strip)
_filename=./FreeCAD_${pkgver//_/-}-Linux-Conda_Py3Qt5_glibc2.12-${arch}.AppImage
prepare() {
cd "${srcdir}"
chmod +x ${_filename}
${_filename} --appimage-extract
patch -Np0 < ./freecad.desktop.patch
}
package() {
install -Dm755 "${srcdir}/${_filename}" "${pkgdir}/opt/appimages/freecad.AppImage"
install -Dm755 "${srcdir}/freecad.sh" "${pkgdir}/usr/bin/freecad"
install -dm755 "${pkgdir}/usr/share/"
cp -r --no-preserve=mode,ownership "${srcdir}/squashfs-root/usr/share/icons" "${pkgdir}/usr/share/"
install -Dm644 "${srcdir}/squashfs-root/freecad.desktop" "${pkgdir}/usr/share/applications/freecad.desktop"
}
# vim:set ts=2 sw=2 et:
|