blob: 2f00eb83095be42d8e0ff4b1265cf63bdab2256c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Michael Straube <michael.straubej@gmail.com>
# Contributor: Robert Knauer <robert@privatdemail.net>
pkgname=freedoko
pkgver=0.7.23c
pkgrel=1
pkgdesc="Free implementation of the card game Doppelkopf"
arch=('x86_64')
url="http://free-doko.sourceforge.net/FreeDoko.html"
license=('GPL3' 'custom:InnoCard')
depends=('gtkmm3' 'freealut')
makedepends=('asciidoc' 'texlive-latexextra' 'w3m' 'dos2unix' 'rsync')
source=("https://downloads.sourceforge.net/free-doko/FreeDoko_$pkgver.src.zip"
"https://downloads.sourceforge.net/free-doko/FreeDoko_$pkgver.Linux.zip"
"freedoko-install-directories.patch")
noextract=("FreeDoko_$pkgver.Linux.zip")
sha512sums=('0aa25ed80e250ddd6269fe1d42a6f439eb3203430c56304ed5502159085e264b7f0fc1a374dbbbe67bcdc7af846fc4cdf94d337c94a8d68ea73f828b0c19eeea'
'c285b3e2e556b2434d5cf2daf9d277a51b07739221dcd23a34529fbe4856035a1ace9953d223884234c91531ef1877da8a8a8d942b8bf7fdcd031f7d7d7e4f46'
'602f53bfd4c4c49824400a36e4655dc6f6d5692b7277489f8e5f9f9d9d4d90eb086a4d142736e76edc2c8864430d8cbf5fa403bb25497b2c6a510a1979fe7650')
prepare() {
cd FreeDoko_$pkgver
patch -Np1 < ../freedoko-install-directories.patch
# disable manual binary stripping
sed -i '/$(MAKE) strip/d' src/Makefile
# extract InnoCard from binary release archive
bsdtar -C data/cardsets --strip-components=2 \
-xf ../FreeDoko_$pkgver.Linux.zip FreeDoko_$pkgver/cardsets/InnoCard
}
build() {
cd FreeDoko_$pkgver
export CXXFLAGS+=' -std=c++17'
make compile
make documentation
}
package() {
cd FreeDoko_$pkgver
make DESTDIR="$pkgdir" install
install -d "$pkgdir"/usr/share/freedoko/cardsets
cp -r data/cardsets/InnoCard "$pkgdir"/usr/share/freedoko/cardsets
install -Dm644 data/cardsets/InnoCard/*.{txt,pdf} \
-t "$pkgdir"/usr/share/licenses/$pkgname/InnoCard
}
|