blob: 01e95277ad253ab2c042bac17f88ba1b435cf244 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Michael Straube <michael.straube@posteo.de>
# Contributor: Robert Knauer <robert@privatdemail.net>
pkgname=freedoko-git
pkgver=0.7.20.r154.g7ca0fa85d
pkgrel=1
pkgdesc="Free implementation of the card game Doppelkopf (developer version)"
arch=('x86_64')
url="http://free-doko.sourceforge.net"
license=('GPL')
depends=('gtkmm3' 'freealut')
makedepends=('git' 'asciidoc' 'texlive-latexextra' 'w3m' 'dos2unix' 'rsync')
conflicts=('freedoko')
provides=('freedoko')
source=("git+https://gitlab.com/dknof/FreeDoko.git"
"freedoko-install-directories.patch")
sha256sums=('SKIP'
'3bd03f2d57327b97ea1ab22ff210381f0ff60d8b1db794f07cda5ef01d7e7df4')
pkgver() {
cd FreeDoko
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd FreeDoko
patch -p1 -i ../freedoko-install-directories.patch
sed -i '/$(MAKE) strip/d' src/Makefile
}
build() {
cd FreeDoko
export CXXFLAGS+=' -std=c++17'
make compile
make documentation
}
package() {
cd FreeDoko
make DESTDIR="$pkgdir" install
}
|