summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1f4d2a2a65a6a0c68414625d7af1d423bec65962 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer:  Frederic Bezies <fredbezies at gmail.com>
# Contributor: Edoardo Maria Elidoro <edoardo.elidoro@gmail.com>
# Contributor: Christoph Zeiler <rabyte*gmail>
# Contributor: felix <at yandex.com, m.p.isaev>

pkgname=({freedm,freedoom}-git)
pkgbase=freedoom-git
pkgdesc="Free game data files for Doom gaming engines"
pkgver=0.12.0.r52.gbdb986eb
pkgrel=1
epoch=1
arch=('any')
url="http://freedoom.github.io/"
license=('BSD')
makedepends=('asciidoc' 'deutex' 'python' 'python-pillow' 'git')
source=(git+https://github.com/freedoom/freedoom.git)
sha256sums=(SKIP)

pkgver() {
  cd "$srcdir/freedoom"
  git describe --long | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/freedoom"
  make
}

package_freedm-git() {
  provides=('freedoom' 'freedm')

  cd "$srcdir/freedoom"
  make prefix=/usr DESTDIR="$pkgdir" install-freedm
}

package_freedoom-git() {
  provides=('freedoom' 'freedoom1' 'freedoom2')

  cd "$srcdir/freedoom"
  make prefix=/usr DESTDIR="$pkgdir" install-freedoom
}