summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9babe2e7a0b432629874aa6c843ed8dd53596383 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer:  Frederic Bezies <fredbezies at gmail.com>
# Contributor: Edoardo Maria Elidoro <edoardo.elidoro@gmail.com>
# Contributor: Christoph Zeiler <rabyte*gmail>
# Contributor: felix <at yandex.com, m.p.isaev>

pkgname=({freedm,freedoom1,freedoom2}-git)
pkgbase=freedoom-git
pkgdesc="Free game data files for Doom gaming engines"
pkgver=0.9.r129.g2e9d764
pkgrel=1
epoch=1
arch=('any')
url="http://freedoom.github.io/"
license=('BSD')
makedepends=('git' 'imagemagick' 'deutex-devel' 'python2' 'python2-virtualenv' 'asciidoc')
source=(git+https://github.com/freedoom/freedoom.git)
md5sums=(SKIP)

pkgver() {
  cd "$srcdir/freedoom"
  git describe | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/freedoom"
  make
}

package_freedm-git() {
  provides=('freedoom' 'freedm')

  cd "$srcdir/freedoom"
  make DESTDIR="$pkgdir" prefix=/usr install-freedm
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/freedm/COPYING
}

package_freedoom1-git() {
  provides=('freedoom' 'freedoom1')

  cd "$srcdir/freedoom"
  make DESTDIR="$pkgdir" prefix=/usr install-freedoom1
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/freedoom1/COPYING
}

package_freedoom2-git() {
  provides=('freedoom' 'freedoom2')

  cd "$srcdir/freedoom"
  make DESTDIR="$pkgdir" prefix=/usr install-freedoom2
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/freedoom2/COPYING
}