summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 515b648ab63d7ced67789bf98b2fdb826bfd8b11 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org>
# Maintainer: Petrov Vlad <petrov.vlad@ya.ru>
# Contributor: Sergey Kostyaev <feo.me@ya.ru>

pkgname=freelib-git
pkgver=6.0.93.r33.g1e83b5f
pkgrel=2
pkgdesc="Freelib is book library manager"
arch=(x86_64)
url="https://github.com/petrovvlad/freeLib"
license=(GPL3)
depends=(qt6-base qt6-svg qt6-httpserver quazip-qt6)
optdepends=('kindlegen: convert to EPUB, MOBI, AZW3'
            'djvulibre: djvu covers')
makedepends=(git cmake)
provides=(freelib)
conflicts=(freelib)
source=("git+https://github.com/petrovvlad/freeLib.git"
        #"git+https://github.com/stachenov/quazip.git"
        "freelib-SmtpClient-for-Qt::git+https://github.com/petrovvlad/SmtpClient-for-Qt.git")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd "freeLib"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "freeLib"
  git submodule init
  #git config submodule.freeLib/src/quazip.url     "${srcdir}/quazip"
  git config submodule.freeLib/src/SmtpClient.url "${srcdir}/freelib-SmtpClient-for-Qt"
  git -c protocol.file.allow=always submodule update
}

build() {
  cmake -B build -S "freeLib" -Wno-dev \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DFREELIB_QT_MAJOR_VERSION=6

  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}