blob: 7ecd06a3765032c31d9eacc6c0dcdaecd1acb642 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
# Maintainer: Fijxu <fijxu [at] nadeko [dot] net>
# Contributor: peacey <peaceyall AT gmail.com>
# Contributor: DasSkelett <dasskelett AT dasskelett.dev>
# Contributor: Kasei Wang <kasei AT kasei.im>
# Contributor: Bartłomiej Piotrowski <bpiotrowski AT archlinux.org>
# Contributor: Sébastien Luttringer
# Contributor: Drew DeVault
_pkgbase=nginx
_pkgname=freenginx-mainline
pkgbase=freenginx-mainline-hg
pkgname=(freenginx-mainline-hg freenginx-mainline-hg-src)
pkgver=1.25.4.r9220.8b8b2e1aa77a
pkgrel=1
pkgdesc='Lightweight HTTP server and IMAP/POP3 proxy server. Mercurial repo version.'
arch=('i686' 'x86_64')
url='https://freenginx.org'
license=('custom')
makedepends=(mercurial pcre2 zlib openssl geoip mailcap libxcrypt)
checkdepends=(perl perl-gd perl-io-socket-ssl perl-fcgi perl-cache-memcached memcached ffmpeg)
backup=('etc/nginx/fastcgi.conf'
'etc/nginx/fastcgi_params'
'etc/nginx/koi-win'
'etc/nginx/koi-utf'
'etc/nginx/nginx.conf'
'etc/nginx/scgi_params'
'etc/nginx/uwsgi_params'
'etc/nginx/win-utf'
'etc/logrotate.d/nginx')
install=nginx.install
provides=('nginx' 'nginx-mainline')
conflicts=('nginx')
source=("hg+https://freenginx.org/hg/nginx"
"nginx.service"
"logrotate")
sha512sums=('SKIP'
'ca7d8666177d31b6c4924e9ab44ddf3d5b596b51da04d38da002830b03bd176d49354bbdd2a496617d57f44111ad59833296af87d03ffe3fca6b99327a7b4c3c'
'2f4dfcfa711b8bcbc5918ba635f5e430ef7132e66276261ade62bb1cba016967432c8dce7f84352cb8b07dc7c6b18f09177aa3eb92c8e358b2a106c8ca142fe9')
_common_flags=(
--with-compat
--with-debug
--with-file-aio
--with-http_addition_module
--with-http_auth_request_module
--with-http_dav_module
--with-http_degradation_module
--with-http_flv_module
--with-http_geoip_module
--with-http_gunzip_module
--with-http_gzip_static_module
--with-http_mp4_module
--with-http_random_index_module
--with-http_realip_module
--with-http_secure_link_module
--with-http_slice_module
--with-http_ssl_module
--with-http_stub_status_module
--with-http_sub_module
--with-http_v2_module
--with-http_v3_module
--with-mail
--with-mail_ssl_module
--with-pcre-jit
--with-stream
--with-stream_geoip_module
--with-stream_realip_module
--with-stream_ssl_module
--with-stream_ssl_preread_module
--with-threads
)
_mainline_flags=(
)
pkgver() {
cd "$srcdir/$_pkgbase"
printf "%s.r%s.%s" "$(hg tags -q | grep -v tip | head -n1 | sed s/^release-//)" "$(hg identify -n)" "$(hg identify -i)"
}
prepare() {
cp -r $_pkgbase{,-src}
}
build() {
cd "$srcdir/$_pkgbase"
./auto/configure \
--prefix=/etc/nginx \
--conf-path=/etc/nginx/nginx.conf \
--sbin-path=/usr/bin/nginx \
--pid-path=/run/nginx.pid \
--lock-path=/run/lock/nginx.lock \
--user=http \
--group=http \
--http-log-path=/var/log/nginx/access.log \
--error-log-path=stderr \
--http-client-body-temp-path=/var/lib/nginx/client-body \
--http-proxy-temp-path=/var/lib/nginx/proxy \
--http-fastcgi-temp-path=/var/lib/nginx/fastcgi \
--http-scgi-temp-path=/var/lib/nginx/scgi \
--http-uwsgi-temp-path=/var/lib/nginx/uwsgi \
--with-cc-opt="$CFLAGS $CPPFLAGS" \
--with-ld-opt="$LDFLAGS" \
"${_common_flags[@]}" \
"${_mainline_flags[@]}"
make
}
package_freenginx-mainline-hg() {
pkgdesc='Lightweight HTTP server and IMAP/POP3 proxy server, mainline release'
depends=('pcre2' 'zlib' 'openssl' 'geoip' 'mailcap' 'libxcrypt')
provides=($_pkgbase)
conflicts=($_pkgbase)
cd $_pkgbase
make DESTDIR="$pkgdir" install
sed -e 's|\<user\s\+\w\+;|user http;|g' \
-e '44s|html|/usr/share/nginx/html|' \
-e '54s|html|/usr/share/nginx/html|' \
-i "$pkgdir"/etc/nginx/nginx.conf
rm "$pkgdir"/etc/nginx/*.default
rm "$pkgdir"/etc/nginx/mime.types # in mailcap
install -d "$pkgdir"/var/lib/nginx
install -dm700 "$pkgdir"/var/lib/nginx/proxy
chmod 755 "$pkgdir"/var/log/nginx
chown root:root "$pkgdir"/var/log/nginx
install -d "$pkgdir"/usr/share/nginx
mv "$pkgdir"/etc/nginx/html/ "$pkgdir"/usr/share/nginx
install -Dm644 ../logrotate "$pkgdir"/etc/logrotate.d/nginx
install -Dm644 ../nginx.service "$pkgdir"/usr/lib/systemd/system/nginx.service
install -Dm644 docs/text/LICENSE "$pkgdir"/usr/share/licenses/$_pkgbase/LICENSE
rmdir "$pkgdir"/run
install -Dm0644 docs/man/nginx.8 "$pkgdir"/usr/share/man/man8/nginx.8
for i in ftdetect ftplugin indent syntax; do
install -Dm644 contrib/vim/$i/nginx.vim \
"$pkgdir/usr/share/vim/vimfiles/$i/nginx.vim"
done
}
package_freenginx-mainline-hg-src() {
pkgdesc="Source code of $_pkgname-mainline-hg $pkgver, useful for building modules"
provides=('nginx-src' 'nginx-mainline-src')
conflicts=($_pkgbase-src)
install -d "$pkgdir/usr/src"
test -d "$pkgdir/usr/src/nginx" && rm -r "$pkgdir/usr/src/nginx"
cp -r "$srcdir/$_pkgbase-src" "$pkgdir/usr/src/nginx"
# Delete the .hg directory, it is huge and not needed
rm -r "$pkgdir"/usr/src/nginx/{.hg,.hgtags}
# Link the 'configure' script to its location in release tarballs,
# as this is where modules expect it
ln -s /usr/src/nginx/auto/configure "$pkgdir/usr/src/nginx"
}
# vim:set ts=2 sw=2 et:
|